当前位置: 好代码 >> 网络编程 >> .Net

FireMonkey下的WndProc实现

2012/6/4 14:01:47

因为FireMonkey是为了跨平台而存在的,所以Windows下特有的概念在FMX下是不存在的,比如消息机制
但是你创建一个FM程序,发现仍然可以在Windows下工作,所以它必定是有消息处理机制的,只不过封装了起来,你无法直接操作而已
今天是要在FMX下实现Vcl下的WndProc函数,来达到处理消息的目的

unit Unit1;
interface
uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Classes, FMX.Forms, FMX.Platform.Win, FMX.Types,
FMX.Layouts, FMX.Memo;
type
TForm1 = class(TForm)
Memo1: TMemo;
procedure FormCreate(Sender: TObject);
procedure FormDestroy(Sender: TObject);
private
FHwnd: HWND;                 // 保存窗口句柄
FOldWndProc: LONG;           // 保存原始的消息处理函数
public
function WndProc(Hwnd: HWND; Msg:UINT; wParam: WPARAM; lParam: LPARAM): LRESULT;
end;
var
Form1: TForm1;
implementation
{$R *.fmx}
function WindowProc(Hwnd: HWND; Msg: UINT; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall;
begin
// 因为在通常开发时,需要访问窗口内部的方法或控件等
// 为了方便起见,所以在这里做一个消息转发
Result := Form1.WndProc(Hwnd, Msg, wParam, lParam);
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
// 获得主窗口句柄,在FMX框架下,Handle已经不是本窗口的句柄了,需要转换一下
FHwnd := FmxHandleToHwnd(Handle);
// 保存原始的WindowProc地址
FOldWndProc := GetWindowLongPtr(FHwnd, GWL_WNDPROC);
// 获得消息处理权
SetWindowLongPtr(FHwnd, GWL_WNDPROC, NativeInt(@WindowProc));
end;
procedure TForm1.FormDestroy(Sender: TObject);
begin
// 因为窗口销毁后无法再处理Windows传递来的消息,从而会发生内存访问错误
// 所以在窗口销毁前要把消息处理权移交给原始的WindowProc
SetWindowLongPtr(FHwnd, GWL_WNDPROC, FOldWndProc);
end;
function TForm1.WndProc(Hwnd: HWND; Msg: UINT; wParam: WPARAM; lParam: LPARAM): LRESULT;
begin
Result := 0;
// 这里测试处理鼠标滚轮消息
if Msg = WM_MOUSEWHEEL then
begin
Memo1.Lines.Add('亲~!你使用了鼠标滚轮哦~!');
Exit;
end;
Result := CallWindowProc(Ptr(FOldWndProc), Hwnd, Msg, wParam, lParam);
end;
end.

  

关于好代码 互联网资讯 Seo .Net编程 网站地图

Copyright 2011-2014 HaoGongJu.Net ( 好代码 ) All Rights Reserved